FrostUtil API

Functions

• GetAPIVersion
• GetFrostfallVersion
• IsPlayerNearFire
• GetPlayerHeatSourceLevel
• GetPlayerHeatSourceDistance
• IsPlayerTakingShelter
• IsNearFastTravelException
• GetCurrentTemperature
• GetCurrentWeatherActual
• GetWeatherClassificationActual
• IsWeatherSevere
• AddSevereWeather
• RemoveSevereWeather
• IsWeatherOvercast
• AddOvercastWeather
• RemoveOvercastWeather
• IsRefInOblivion
• IsOblivionWorldspace
• AddOblivionWorldspace
• RemoveOblivionWorldspace
• IsExposureException
• AddExposureException
• RemoveExposureException
• IsFastTravelException
• AddFastTravelException
• RemoveFastTravelException
• IsSleepException
• AddSleepException
• RemoveSleepException
• AddFastTravelWorldspaceException
• RemoveFastTravelWorldspaceException
• GetPlayerWetness
• GetPlayerWetnessLevel
• ModPlayerWetness
• GetPlayerExposure
• GetPlayerExposureLevel
• ModPlayerExposure
• GetPlayerWarmth
• GetPlayerCoverage
• GetPlayerArmorWarmth
• GetPlayerArmorCoverage

Events

• Frostfall_OnPlayerStartSwimming
• Frostfall_OnPlayerStopSwimming
• Frostfall_Loaded
• Frost_OnRescuePlayer
• Frost_OnTamrielRegionChange
• Frost_OnInnerFireMeditate

Functions

GetAPIVersion

Get the FrostUtil API version number.

Api version added

1

Syntax

float function GetAPIVersion() global

Parameters

None

Return Value

The FrostUtil API version number. This is NOT the same thing as the version number of Frostfall. FrostUtil's API version number will increment only when changes have been made to the API itself.

Examples

float ver = FrostUtil.GetAPIVersion()

---

GetFrostfallVersion

Get the Frostfall mod version number.

Api version added

1

Syntax

float function GetFrostfallVersion() global

Parameters

None

Return Value

The Frostfall version number.

Examples

float ver = FrostUtil.GetFrostfallVersion()

---

IsPlayerNearFire

Whether or not the player is currently near a fire.

Api version added

1

Syntax

bool function IsPlayerNearFire() global

Parameters

None

Return Value

True if near a fire; false otherwise.

Examples

;Is the player near a fire?
bool near_fire = FrostUtil.IsPlayerNearFire()

Notes

This does NOT indicate if the player is near a heat source; there are heat sources that are not fires. Fires have special properties in Frostfall and Campfire, which include drying the player when wet, and being able to cook food using a cooking pot.

To determine if the player is near a heat source of any kind, use GetPlayerHeatSourceLevel() instead.

Keep in mind that Frostfall's Heat Source System only updates every 5 seconds. Therefore, the data returned by this function is not real-time.

---

GetPlayerHeatSourceLevel

The level (size) of the player's current nearby heat source.

Api version added

1

Syntax

int function GetPlayerHeatSourceLevel() global

Parameters

None

Return Value

Possible return values:

• 0 = Player is not near a heat source.

• 1 = Current heat source is "small" (e.g. bowls of burning embers, "fragile" campfires in Campfire)

• 2 = Current heat source is "medium" (e.g. most campfires and other fireplaces)

• 3 = Current heat source is "large" (e.g. giant campfires, "roaring" campfires in Campfire)

Examples

;Is the player near heat?
int heat = FrostUtil.GetPlayerHeatSourceLevel()
if heat > 0
    debug.notification("Player is near a heat source!")
endif

Notes

This function does NOT determine if the heat source is a fire or not; there are heat sources that are not fires. To determine if the player is near a fire, use IsPlayerNearFire().

Keep in mind that Frostfall's Heat Source System only updates every 5 seconds. Therefore, the data returned by this function is not real-time.

---

GetPlayerHeatSourceDistance

The distance from the player to the player's current nearby heat source.

Api version added

1

Syntax

float function GetPlayerHeatSourceDistance() global

Parameters

None

Return Value

• 0.0 to 600.0 - The distance from the player to the heat source. Frostfall does not detect heat sources more than 600 units away.

• -1.0 - No current heat source detected.

Examples

;How far away is the heat source?
float dist = FrostUtil.GetPlayerHeatSourceDistance()
if dist <= 300.0
    debug.notification("The player is really close to the heat source!")
endif

Notes

Keep in mind that Frostfall's Heat Source System only updates every 5 seconds. Therefore, the data returned by this function is not real-time.

---

IsPlayerTakingShelter

Whether or not the player is taking shelter underneath an outcropping / building. If the player is "sheltered", the player will dry off if wet, regardless of current weather conditions.

Api version added

1

Syntax

bool function IsPlayerTakingShelter() global

Parameters

None

Return Value

True if taking shelter, false if not.

Examples

;Is the player underneath something?
bool sheltered = FrostUtil.IsPlayerTakingShelter()

Notes

This function does not return true if the player is inside a Campfire-based tent; it only returns true if a ray emitting upward from the player's head collides with an obstruction. For tent detection, use CampUtil.GetCurrentTent().

---

IsNearFastTravelException

Whether or not the player near a "fast travel exception". If a player is nearby one of these objects, the Exposure System will re-enable the player's Fast Travel controls. This is used in cases where there is an expectation for Fast Travel be enabled when near these objects (like Apocrypha's Black Books.)

Api version added

1

Syntax

bool function IsNearFastTravelException() global

Parameters

None

Return Value

True if near a "fast travel exception" object, false if not.

Examples

;Is the player near a fast travel exception?
bool near_ft_exception = FrostUtil.IsNearFastTravelException()

---

GetCurrentTemperature

Returns the current area temperature, based on location, weather, weather severity, and time of day.

Api version added

1

Syntax

int function GetCurrentTemperature() global

Parameters

None

Return Value

• Greater than 10: A "warm" area. Exposure will decrease. The higher the number, the faster it will decrease.

• 10: A "neutral" area. Exposure will not increase or decrease.

• Less than 10: A "cold" area. Exposure will increase. The lower the number, the faster it will increase.

Examples

int temp = FrostUtil.GetCurrentTemperature()
if temp < 10
    debug.notification("It's cold!")
endif

Notes

The return values of this function correspond very roughly with degrees celsius.

---

GetCurrentWeatherActual

Returns the current weather somewhat more accurately than the default GetCurrentWeather() function. This function returns the outgoing weather if the weather is currently transitioning out (and thus is still currently visible). Otherwise, returns the current weather.

Api version added

1

Syntax

Weather function GetCurrentWeatherActual() global

Parameters

None

Return Value

The current weather.

Examples

;What is the current weather, really?
Weather wthr = FrostUtil.GetCurrentWeatherActual()

---

GetWeatherClassificationActual

Returns the classification of the weather returned by GetCurrentWeatherActual().

Api version added

1

Syntax

int function GetWeatherClassificationActual(Weather akWeather) global

Parameters

• akWeather: The Weather to check.

Return Value

The current weather classification.

Examples

;What is the current weather classification, really?
int class = FrostUtil.GetWeatherClassificationActual()

---

IsWeatherSevere

True if this weather is in the severe weather list that Frostfall maintains, false if not.

Api version added

1

Syntax

bool function IsWeatherSevere(Weather akWeather) global

Parameters

• akWeather: The Weather to check.

Return Value

Whether or not this weather is severe.

Examples

if FrostUtil.IsWeatherSevere(FrostUtil.GetCurrentWeatherActual())
    debug.notification("Better stay indoors!")
endif

---

AddSevereWeather

Adds a weather to the severe weather list that Frostfall maintains.

Api version added

2

Syntax

function AddSevereWeather(Weather akWeather) global

Parameters

None

Return Value

None

Examples

;Add my custom blizzard to the severe weather list
FrostUtil.AddSevereWeather(my_crazy_blizzard)

---

RemoveSevereWeather

Removes a weather from the severe weather list that Frostfall maintains. Only weather forms added to the list via AddSevereWeather can be removed.

Api version added

2

Syntax

function RemoveSevereWeather(Weather akWeather) global

Parameters

None

Return Value

None

Examples

;Remove my custom blizzard to the severe weather list
FrostUtil.RemoveSevereWeather(my_crazy_blizzard)

---

IsWeatherOvercast

True if this weather is in the overcast weather list that Frostfall maintains, false if not.

Api version added

1

Syntax

bool function IsWeatherOvercast(Weather akWeather) global

Parameters

• akWeather: The Weather to check.

Return Value

Whether or not this weather is Overcast.

Examples

if FrostUtil.IsWeatherOvercast(FrostUtil.GetCurrentWeatherActual())
    debug.notification("Man, it's dreary out.")
endif

Notes

Weather in the overcast weather list must be marked with the "Cloudy" classification. This list is necessary because the base Skyrim game often uses the "Cloudy" classification to denote fog weathers instead of cloudy weathers, and Frostfall needs to be able to differentiate between them.

---

AddOvercastWeather

Adds a weather to the overcast weather list that Frostfall maintains.

Api version added

2

Syntax

function AddOvercastWeather(Weather akWeather) global

Parameters

None

Return Value

None

Examples

;Add my custom weather to the overcast weather list
FrostUtil.AddOvercastWeather(my_dreary_weather)

Notes

Weather in the overcast weather list must be marked with the "Cloudy" classification. This list is necessary because the base Skyrim game often uses the "Cloudy" classification to denote fog weathers instead of cloudy weathers, and Frostfall needs to be able to differentiate between them.

---

RemoveOvercastWeather

Removes a weather from the overcast weather list that Frostfall maintains. Only weather forms added to the list via AddOvercastWeather can be removed.

Api version added

2

Syntax

function RemoveOvercastWeather(Weather akWeather) global

Parameters

None

Return Value

None

Examples

;Remove my custom weather from the overcast weather list
FrostUtil.RemoveOvercastWeather(my_dreary_weather)

Notes

Weather in the overcast weather list must be marked with the "Cloudy" classification. This list is necessary because the base Skyrim game often uses the "Cloudy" classification to denote fog weathers instead of cloudy weathers, and Frostfall needs to be able to differentiate between them.

---

IsRefInOblivion

Whether or not the reference is in a base game or DLC Oblivion worldspace.

Api version added

1

Syntax

bool function IsRefInOblivion(ObjectReference akReference) global

Parameters

• akReference: The object reference to check.

Return Value

True if the reference is in Oblivion.

Examples

;Is the box in Oblivion?
if IsRefInOblivion(Box)
    Debug.Trace("Box is in Oblivion!")
endif

Notes

• The following Worldspaces are considered Oblivion worldspaces:

• Soul Cairn

• Apocrypha

---

IsOblivionWorldspace

Whether or not the worldspace is a base game or DLC Oblivion worldspace.

Api version added

1

Syntax

bool function IsOblivionWorldspace(Worldspace akWorldspace) global

Parameters

• akWorldspace: The worldspace to check.

Return Value

True if the worldspace is a plane of Oblivion.

Examples

;Is the box in Oblivion?
if IsOblivionWorldspace(infernal_realm)
    Debug.Trace("This is a plane of Oblivion!")
endif

Notes

• The following Worldspaces are considered Oblivion worldspaces by default:

• Soul Cairn

• Apocrypha

---

AddOblivionWorldspace

Adds a worldspace to the Oblivion worldspace list that Frostfall maintains. The player does not gain exposure when in planes of Oblivion.

Api version added

2

Syntax

function AddOblivionWorldspace(Worldspace akWorldspace) global

Parameters

None

Return Value

None

Examples

;Add my custom worldspace to the Oblivion worldspace list
FrostUtil.AddOblivionWorldspace(my_infernal_realm)

---

RemoveOblivionWorldspace

Removes a worldspace from the Oblivion worldspace list that Frostfall maintains. The player does not gain exposure when in planes of Oblivion. Only Worldspace forms added to the list via AddOblivionWorldspace can be removed.

Api version added

2

Syntax

function RemoveOblivionWorldspace(Worldspace akWorldspace) global

Parameters

None

Return Value

None

Examples

;Remove my custom worldspace from the Oblivion worldspace list
FrostUtil.RemoveOblivionWorldspace(my_infernal_realm)

---

IsExposureException

True if this form is in the exposure exception list that Frostfall maintains, false if not. When the player goes near this object (600 units or less), the player will not gain or lose exposure.

Api version added

2

Syntax

bool function IsExposureException(Form akBaseObject) global

Parameters

• akBaseObject: The form to check.

Return Value

Whether or not this form is an exposure exception.

Examples

;Will I turn off exposure mechanics near the dragon?
if FrostUtil.IsExposureException(SuperDragon)
    debug.notification("Guess I won't freeze to death near the Super Dragon.")
endif

---

AddExposureException

Adds a form to the list of exposure exception objects that Frostfall maintains. When the player goes near this object (600 units or less), the player will not gain or lose exposure.

Api version added

2

Syntax

function AddExposureException(Form akBaseObject) global

Parameters

None

Return Value

None

Examples

;Suspend exposure gain and loss near the power stone
FrostUtil.AddExposureException(power_stone)

---

RemoveExposureException

Removes a form from the list of exposure exception objects that Frostfall maintains. Only forms added to the list via AddExposureException can be removed.

Api version added

2

Syntax

function RemoveExposureException(Form akBaseObject) global

Parameters

None

Return Value

None

Examples

;No longer suspend exposure near the power stone
FrostUtil.RemoveExposureException(power_stone)

---

IsFastTravelException

True if this form is in the fast travel exception list that Frostfall maintains, false if not. When the player goes near this object (600 units or less), fast travel controls will be re-enabled regardless of their fast travel settings.

Api version added

2

Syntax

bool function IsFastTravelException(Form akBaseObject) global

Parameters

• akBaseObject: The form to check.

Return Value

Whether or not this form is a fast travel exception.

Examples

;Will I enable fast travel near the carriage?
if FrostUtil.IsFastTravelException(carriage)
    debug.notification("Sally forth!")
endif

---

AddFastTravelException

Adds a form to the list of fast travel exception objects that Frostfall maintains. When the player goes near this object (600 units or less), fast travel controls will be re-enabled regardless of their fast travel settings.

Api version added

2

Syntax

function AddFastTravelException(Form akBaseObject) global

Parameters

None

Return Value

None

Examples

;Enable fast travel when near the horse.
FrostUtil.AddFastTravelException(my_horse)

---

RemoveFastTravelException

Removes a form from the list of fast travel exception objects that Frostfall maintains. Only forms added to the list via AddFastTravelException can be removed.

Api version added

2

Syntax

function RemoveFastTravelException(Form akBaseObject) global

Parameters

None

Return Value

None

Examples

;No longer enable fast travel near the horse
FrostUtil.RemoveFastTravelException(my_horse)

---

IsSleepException

True if this form is in the sleep exception list that Frostfall maintains, false if not.

Api version added

2

Syntax

bool function IsSleepException(Form akBaseObject) global

Parameters

• akBaseObject: The form to check.

Return Value

Whether or not this weather is Overcast.

Examples

if FrostUtil.IsSleepException(my_bedroll)
    debug.notification("Time to hit the sack!")
endif

Notes

When the player goes near this object (600 units or less), the player will be able to sleep. This is important if the player has "Disable Waiting Outdoors" enabled, which prevents sleeping unless near an object in this list.

Tents created with the Campfire Dev Kit are automatically sleep exception objects. Conjured shelters are not and must be added using AddSleepException().

---

AddSleepException

Adds a form to the list of sleep exception objects that Frostfall maintains. When the player goes near this object (600 units or less), the player will be able to sleep. This is important if the player has "Disable Waiting Outdoors" enabled, which prevents sleeping unless near an object in this list.

Api version added

2

Syntax

function AddSleepException(Form akBaseObject) global

Parameters

• akBaseObject: The form to add.

Return Value

None

Examples

;Enable ability to sleep near my bedroll.
FrostUtil.AddSleepException(my_bedroll)

---

RemoveSleepException

Removes a form from the list of sleep exception objects that Frostfall maintains. Only forms added to the list via AddSleepException can be removed.

Api version added

2

Syntax

function RemoveSleepException(Form akBaseObject) global

Parameters

• akBaseObject: The form to remove.

Return Value

None

Examples

;No longer enable fast travel near the horse
FrostUtil.RemoveSleepException(my_horse)

---

AddFastTravelWorldspaceException

Adds a worldspace to the list of worldspaces that Frostfall maintains where fast travel controls should always be enabled.

Api version added

2

Syntax

function AddFastTravelWorldspaceException(Worldspace akWorldspace) global

Parameters

None

Return Value

None

Examples

;Add my custom worldspace to the fast travel exception worldspace list
FrostUtil.AddFastTravelWorldspaceException(my_realm)

---

RemoveFastTravelWorldspaceException

Adds a worldspace to the list of worldspaces that Frostfall maintains where fast travel controls should always be enabled. Only Worldspace forms added to the list via AddFastTravelWorldspaceException can be removed.

Api version added

2

Syntax

function RemoveFastTravelWorldspaceException(Worldspace akWorldspace) global

Parameters

None

Return Value

None

Examples

;Remove my custom worldspace from the fast travel exception worldspace list
FrostUtil.RemoveFastTravelWorldspaceException(my_realm)

---

GetPlayerWetness

Return the player's current wetness value.

Api version added

1

Syntax

float function GetPlayerWetness() global

Parameters

None

Return Value

• The player's current wetness value.

• 0.0 = Not wet

• >0.0 - 199.9 = Damp

• 200.0 - 549.9 = Wet

• 550.0 - 750.0 = Drenched

Examples

float wetness = FrostUtil.GetPlayerWetness()

---

GetPlayerWetnessLevel

Return the player's current wetness level. May be easier to use than GetPlayerWetness() if you don't need to know the actual wetness value.

Api version added

1

Syntax

int function GetPlayerWetnessLevel() global

Parameters

None

Return Value

• The player's current wetness level.

• 0 = Not wet

• 1 = Damp

• 2 = Wet

• 3 = Drenched

Examples

;Is the player drenched?
int wet_level = FrostUtil.GetPlayerWetnessLevel()
if wet_level == 3
    debug.notification("You're soaked!")
endif

---

ModPlayerWetness

Modify the player's current wetness by the given amount. Using this function will correctly process the wetness change and notify the UI layer (meters, etc) of the change and display them as appropriate. Using this function is the only safe method of directly modifying the player's wetness value.

Api version added

2

Syntax

function ModPlayerWetness(float amount, float limit = -1.0) global

Parameters

• amount: The amount to modify the player's wetness by. Positive numbers increase wetness, negative values decrease wetness.

• limit (optional): The value at which you should stop the wetness change, if this value is reached. A value of -1.0 indicates that there is no limit. (Example: calling FrostUtil.ModPlayerWetness(35.0, 50.0) when the player's current wetness is 40.0 will increase the player's wetness to 50.0, not 75.0)

Return Value

None

Examples

;The player did something that should make them dry off.
FrostUtil.ModPlayerWetness(-15.0)
;The player did something that should make them dry off, but not below "Wet".
FrostUtil.ModPlayerWetness(-15.0, 200.0)
;The player did something that should make them wetter.
FrostUtil.ModPlayerWetness(20.0)
;The player did something that should make them wetter, but not above "Wet".
FrostUtil.ModPlayerWetness(20.0, 200.0)

---

GetPlayerExposure

Return the player's current exposure value.

Api version added

1

Syntax

float function GetPlayerExposure() global

Parameters

None

Return Value

• The player's current exposure.

• 0.0 - 19.9 = Warm

• 20.0 - 39.9 = Comfortable

• 40.0 - 59.9 = Cold

• 60.0 - 79.9 = Very Cold

• 80.0 - 99.9 = Freezing

• 100.0 - 120.0 = Freezing to Death

Examples

;Is the player cold?
float exp = FrostUtil.GetPlayerExposure()
if exp >= 40.0
    debug.notification("Brrr!")
endif

---

GetPlayerExposureLevel

Return the player's current exposure level. May be easier to use than GetPlayerExposure() if you don't need to know the actual exposure value.

Api version added

1

Syntax

int function GetPlayerExposureLevel() global

Parameters

None

Return Value

• The player's current exposure level.

• -1 = Completely Warm

• 0 = Warm

• 1 = Comfortable

• 2 = Cold

• 3 = Very Cold

• 4 = Freezing

• 5 = Freezing to Death

• 6 = Maximum Exposure

Examples

;Is the player cold?
float exp_level = FrostUtil.GetPlayerExposureLevel()
if exp_level >= 2
    debug.notification("Brrr!")
endif

---

ModPlayerExposure

Modify the player's current exposure by the given amount. Using this function will correctly process the exposure change and notify the UI layer (meters, etc) of the change and display them as appropriate. Using this function is the only safe method of directly modifying the player's exposure value.

Api version added

1

Syntax

function ModPlayerExposure(float amount, float limit = -1.0) global

Parameters

• amount: The amount to modify the player's exposure by. Positive numbers increase exposure, negative values decrease exposure.

• limit (optional): The value at which you should stop the exposure change, if this value is reached. A value of -1.0 indicates that there is no limit. (Example: calling FrostUtil.ModPlayerExposure(35.0, 50.0) when the player's current exposure is 40.0 will increase the player's exposure to 50.0, not 75.0)

Return Value

None

Examples

;The player did something that should make them warmer.
FrostUtil.ModPlayerExposure(-15.0)
;The player did something that should make them warmer, but not below "Cold".
FrostUtil.ModPlayerExposure(-15.0, 40.0)
;The player did something that should make them colder.
FrostUtil.ModPlayerExposure(20.0)
;The player did something that should make them colder, but not above "Freezing".
FrostUtil.ModPlayerExposure(20.0, 80.0)

---

GetPlayerWarmth

Returns the player's total Warmth value.

Api version added

1

Syntax

int function GetPlayerWarmth() global

Parameters

None

Return Value

The player's Warmth value.

Examples

;How bundled up is the player?
int warmth = FrostUtil.GetPlayerWarmth()

---

GetPlayerCoverage

Returns the player's total Coverage value.

Api version added

1

Syntax

int function GetPlayerCoverage() global

Parameters

None

Return Value

The player's Coverage value.

Examples

;How covered is the player?
int coverage = FrostUtil.GetPlayerCoverage()

---

GetPlayerArmorWarmth

Returns the sum of the Warmth values of all gear worn by the player.

Api version added

1

Syntax

int function GetPlayerArmorWarmth() global

Parameters

None

Return Value

The total Warmth of all player worn gear.

Examples

;How warm are the player's clothes?
int gear_warmth = FrostUtil.GetPlayerArmorWarmth()

Notes

There are many different sources of Warmth, so this function does not return the player's total Warmth value. If you want the total Warmth, use GetPlayerWarmth() instead.

---

GetPlayerArmorCoverage

Returns the sum of the Coverage values of all gear worn by the player.

Api version added

1

Syntax

int function GetPlayerArmorCoverage() global

Parameters

None

Return Value

The total Coverage of all player worn gear.

Examples

;How warm are the player's clothes?
int gear_coverage = FrostUtil.GetPlayerArmorCoverage()

Notes

There are many different sources of Coverage, so this function does not return the player's total Coverage value. If you want the total Coverage, use GetPlayerCoverage() instead.

---

Events

Frostfall_OnPlayerStartSwimming

An SKSE Mod Event that is raised when the player begins swimming.

Api version added

1

Syntax

Event Frostfall_OnPlayerStartSwimming()

Parameters

None

Examples

Event OnInit()
    RegisterForModEvent("Frostfall_OnPlayerStartSwimming", "Frostfall_OnPlayerStartSwimming")
endEvent

Event Frostfall_OnPlayerStartSwimming()
    debug.notification("The player started swimming!")
endEvent

---

Frostfall_OnPlayerStopSwimming

An SKSE Mod Event that is raised when the player stops swimming.

Api version added

1

Syntax

Event Frostfall_OnPlayerStopSwimming()

Parameters

None

Examples

Event OnInit()
    RegisterForModEvent("Frostfall_OnPlayerStopSwimming", "Frostfall_OnPlayerStopSwimming")
endEvent

Event Frostfall_OnPlayerStopSwimming()
    debug.notification("The player stopped swimming!")
endEvent

---

Frostfall_Loaded

An SKSE Mod Event that is raised when Frostfall is finished starting up, or after loading a save game with Frostfall enabled.

Api version added

1

Syntax

Event Frostfall_Loaded()

Parameters

None

Examples

Event OnInit()
    RegisterForModEvent("Frostfall_Loaded", "Frostfall_Loaded")
endEvent

Event Frostfall_Loaded()
    debug.notification("Frostfall has finished starting up!")
endEvent

Notes

This event will only be raised if Frostfall is enabled. Therefore, don't rely on this event at game start-up for a critical function as you will not receive it until the player starts up Frostfall or loads a game with Frostfall already enabled.

---

Frost_OnRescuePlayer

An SKSE Mod Event that is raised when the player is rescued when using the Max Exposure Rescue mechanic.

Api version added

1

Syntax

Event Frost_OnRescuePlayer(bool in_water)

Parameters

• in_water: Whether or not the player was swimming when they were rescued (mainly used by the rescue system to select a suitable destination).

Examples

Event OnInit()
    RegisterForModEvent("Frost_OnRescuePlayer", "Frost_OnRescuePlayer")
endEvent

Event Frost_OnRescuePlayer(bool in_water)
    debug.notification("The player was just rescued!")
endEvent

---

Frost_OnTamrielRegionChange

An SKSE Mod Event that is raised when the player moves from one tracked region to another.

Api version added

1

Syntax

Event OnTamrielRegionChange(int region, bool in_region)

Parameters

• region: The ID of the region. See Notes for region IDs.

• in_region: If True, the player is entering this region. If False, the player is leaving it.

Examples

Event OnInit()
    RegisterForModEvent("Frost_OnTamrielRegionChange", "Frost_OnTamrielRegionChange")
endEvent

Event Frost_OnTamrielRegionChange(int region, bool in_region)
    if in_region && region == 11
        debug.notification("The player just entered Solstheim!")
    endif
endEvent

Notes

The following are possible region IDs:

• REGION_UNKNOWN = -1

• REGION_PINEFOREST = 1

• REGION_VOLCANICTUNDRA = 2

• REGION_FALLFOREST = 3

• REGION_REACH = 4

• REGION_TUNDRA = 5

• REGION_TUNDRAMARSH = 6

• REGION_COAST = 7

• REGION_SNOW = 8

• REGION_OBLIVION = 9

• REGION_FALMERVALLEY = 10

• REGION_SOLSTHEIM = 11

• REGION_WYRMSTOOTH = 20

• REGION_DARKEND = 21

---

Frost_OnInnerFireMeditate

An SKSE Mod Event that is raised when the player begins or ends using the Inner Fire ability.

Api version added

1

Syntax

Event Frost_OnInnerFireMeditate(bool abMeditating)

Parameters

• abMeditating: If True, the player entered the Inner Fire state. If False, they have just left it.

Examples

Event OnInit()
    RegisterForModEvent("Frost_OnInnerFireMeditate", "Frost_OnInnerFireMeditate")
endEvent

Event Frost_OnInnerFireMeditate(bool abMeditating)
    if abMeditating
        debug.notification("The player began meditating using Inner Fire!")
    endif
endEvent